How to change the value of a financial default dimension

public static DimensionAttributeValue VKValidateFinancialDimensionValue(DimensionAttribute _dimensionAttribute, str _dimensionValue, boolean _noError = false)
{
    DimensionAttributeValue dimensionAttributeValue;

    dimensionAttributeValue = DimensionAttributeValue::findByDimensionAttributeAndValueNoError(_dimensionAttribute, _dimensionValue, false, true);

    if (!dimensionAttributeValue && !_noError)
    {
        error(strFmt("@SYS342560", _dimensionValue));
    }

    return dimensionAttributeValue;
}

public static DimensionValue VKGetFinancialDimensonValue(DimensionDefault _dimensionDefault, Name _dimensionName)
{
    DefaultDimensionView defaultDimensionView;
    
    select firstonly DisplayValue
    from defaultDimensionView
    where defaultDimensionView.Name == _dimensionName
        && defaultDimensionView.DefaultDimension == _dimensionDefault;

    return defaultDimensionView.DisplayValue;
}

public static DimensionDefault changeFinancialDimensionValue(DimensionDefault _dimensionDefault, Name _dimensionName, DimensionValue _newDimensionValue)
{
    DimensionAttributeValueSetStorage   dimensionAttributeValueSetStorage;
    DimensionAttribute                  dimensionAttribute;
    DimensionValue                      oldDimensionValue;
    DimensionDefault                    newDimensionDefault;

    // Get current value
    oldDimensionValue = BHFFunctions::getFinancialDimensonValue(_dimensionDefault, _dimensionName);

    // Build DimensionAttributeValueSetStorage
    dimensionAttributeValueSetStorage = DimensionAttributeValueSetStorage::find(_dimensionDefault);

    // Remove old dimension value
    dimensionAttribute = DimensionAttribute::findByName(_dimensionName);
    dimensionAttributeValueSetStorage.removeDimensionAttributeValue(
        DimensionAttributeValue::findByDimensionAttributeAndValue(dimensionAttribute, oldDimensionValue).RecId);

    // Set new dimension value
    if(_newDimensionValue)
    {
        dimensionAttributeValueSetStorage.addItem(
            DimensionAttributeValue::findByDimensionAttributeAndValue(dimensionAttribute, _newDimensionValue, false, true));
    }

    newDimensionDefault = dimensionAttributeValueSetStorage.save();

    return newDimensionDefault;
}